C
C Program SMINV to compute symmetric matrix SM2, which is inverse to
C input symetric matrix SM1.
C
C Version: 5.40
C Date: 2000, February 21
C
C Coded by Petr Bulant
C     Department of Geophysics, Charles University Prague,
C     Ke Karlovu 3, 121 16 Praha 2, Czech Republic,
C     E-mail: bulant@seis.karlov.mff.cuni.cz
C
C.......................................................................
C                                                    
C Description of data files:
C
C Input data read from the standard input device (*):
C     The data are read by the list directed input (free format) and
C     consist of a single string 'SEP':
C     'SEP'...String in apostrophes containing the name of the input
C             SEP parameter or history file with the input data.
C     No default, 'SEP' must be specified and cannot be blank.
C
C                                                     
C Input data file 'SEP':
C     File 'SEP' has the form of the SEP
C     parameter file.  The parameters, which do not differ from their
C     defaults, need not be specified in file 'SEP'.
C Data specifying dimensions of the matrices:
C     M1='string'... Name of the file containing a single integer number
C             specifying the number of rows (and columns) of symmetric
C             matrices SM1 and SM2.
C             Default: M1=' ' means that the number is 1.
C Filenames of the files with the matrices:
C     SM1='string' ... Name of the input file containing matrix SM1.
C             No default, 'SM1' must be specified and cannot be blank.
C     SM2='string' ... Name of the output file containing symmetric
C             matrix SM2 which is inverse to matrix SM1.
C             No default, 'SM2' must be specified and cannot be blank.
C     For general description of the files with matrices refer to file
C     forms.htm.
C
C-----------------------------------------------------------------------
C Subroutines and external functions required:
      EXTERNAL SMBLO,IND,ERROR,RSEP1,RSEP3T,RMAT,WMAT,SINV
      INTEGER IND
C     SMBLO,IND ... This file.
C     ERROR ... File error.for.
C     RSEP1,RSEP3T ... File sep.for.
C     RMAT,WMAT ... File forms.for.
C     SINV ... File sinv.for.
C
C Common block /RAMC/:
      INCLUDE 'ram.inc'
C     ram.inc
      INTEGER IRAM(MRAM)
      EQUIVALENCE (IRAM,RAM)
C
      CHARACTER*80 FILSEP,FILE1,FILE2
      CHARACTER*49 TEXT
      INTEGER M1,N,NN,NB,LU1,I1,I2,I3,I4,IBMI,IBMA,IER
      PARAMETER (LU1=1)
      REAL EPS
C
C-----------------------------------------------------------------------
      EPS=0.000001
C
C     Reading a name of the file with the input data:
      WRITE(*,'(A)') '+SMINV: Enter input filename: '
      FILSEP=' '
      READ(*,*) FILSEP
C
C     Reading all the data from the SEP file into the memory:
      IF (FILSEP.NE.' ') THEN
        CALL RSEP1(LU1,FILSEP)
      ELSE
C       SMINV-01
        CALL ERROR('SMINV-01: SEP file not given')
      ENDIF
C
C     Reading the dimension of the matrices:
      CALL RSEP3T('M1',FILE1,' ')
      IF (FILE1.EQ.' ') THEN
        M1=1
      ELSE
        OPEN(LU1,FILE=FILE1,STATUS='OLD')
        READ(LU1,*) M1
        CLOSE(LU1)
      ENDIF
      N=M1
      NN=M1*(M1+1)/2
      IF (3*NN+N+1.GT.MRAM) THEN
C       SMINV-02
        CALL ERROR('SMINV-02: Small dimension MRAM of array RAM')
      END IF
C
C     Reading the names of the files with the matrices:
      CALL RSEP3T('SM1',FILE1,' ')
      IF (FILE1.EQ.' ') THEN
C       SMINV-03
        CALL ERROR('SMINV-03: Input file with matrix SM1 not given')
      ENDIF
      CALL RSEP3T('SM2',FILE2,' ')
      IF (FILE2.EQ.' ') THEN
C       SMINV-04
        CALL ERROR('SMINV-04: Output file with matrix SM2 not given')
      ENDIF
C
C     Reading input matrix:
      CALL RMAT(LU1,FILE1,M1,0,RAM(MRAM-NN+1))
C
      WRITE(*,'(A)') '+SMINV: Working...            '
C
C     Identification of blocks:
      CALL SMBLO(RAM(MRAM-NN+1),N,NN,NB,IRAM(MRAM-NN-N))
C
C     Preparing array for results:
      DO 5, I1=MRAM-2*NN-N,MRAM-NN-N-1
        RAM(I1)=0.
   5  CONTINUE
C
C     Computing the inverse matrix:
      DO 20, I1=1,NB
C       Current block:
        IBMI=IRAM(MRAM-NN-N+I1-1)+1
        IBMA=IRAM(MRAM-NN-N+I1)
C       Moving the block to RAM(1):
        I4=0
        DO 10, I2=IBMI,IBMA
          DO 8, I3=IBMI,I2
            I4=I4+1
            RAM(I4)=RAM(MRAM-NN+IND(I3,I2))
   8      CONTINUE
  10    CONTINUE
        I2=IBMA-IBMI+1
        I3=I2*(I2+1)/2
C       Inverting matrix:
        CALL SINV(RAM,I2,EPS,IER)
        IF(IER.NE.0) THEN
C         SMINV-05
          WRITE(TEXT,'(A,I5,A)')
     *      'SMINV-05: Error',IER,' in subroutine SINV'
          CALL ERROR(TEXT)
        ENDIF
C       Moving the block to RAM(MRAM-NN-N-1-NN+1):
        I4=0
        DO 14, I2=IBMI,IBMA
          DO 12, I3=IBMI,I2
            I4=I4+1
            RAM(MRAM-2*NN-N-1+IND(I3,I2))=RAM(I4)
  12      CONTINUE
  14    CONTINUE
  20  CONTINUE
C
C     Writing output matrix R:
      IF (FILE2.NE.' ') THEN
        CALL WMAT(LU1,FILE2,M1,0,RAM(MRAM-2*NN-N))
      ENDIF
      WRITE(*,'(A)') '+SMINV: Done.                 '
C
      STOP
      END
C
C=======================================================================
C
      SUBROUTINE SMBLO(SM,N,NN,NB,IB)
C
C=======================================================================
C     Subroutine to find blocks of a symmetric matrix
      INTEGER N,NN,NB,IB(0:N)
      REAL SM(NN)
C     Input: SM ... symmetric matrix
C            N  ... number of rows (and columns) of the matrix
C            NN ... N*(N+1)/2
C     Output: NB ... number of blocks of the matrix
C             IB ... array with numbers of lines (and rows), at which
C                    the blocks finish
      INTEGER I1,I2
      EXTERNAL IND
      INTEGER IND
C-----------------------------------------------------------------------
C     Initiating first block:
      NB=1
      IB(0)=0
      IB(1)=1
      I1=0
  10  CONTINUE
C       Loop for lines of the matrix:
        I1=I1+1
        DO 20, I2=N,IB(NB)+1,-1
C         Loop for rows of the line I1:
          IF (SM(IND(I1,I2)).NE.0.) THEN
C           The block is larger:
            IB(NB)=I2
            GOTO 21
          ENDIF
  20    CONTINUE
  21    CONTINUE
        IF (IB(NB).EQ.N) THEN
C         End of the search for blocks.
          RETURN
        ENDIF
        IF (IB(NB).EQ.I1) THEN
C         Block finished, continuing with the next block.
          NB=NB+1
          IB(NB)=I1+1
        ENDIF
      GOTO 10
      END
C=======================================================================
      INTEGER FUNCTION IND(I,J)
      INTEGER I,J
C     I ... Index of a line.
C     J ... Index of a row.
      IND=J*(J-1)/2+I
      RETURN
      END
C
C=======================================================================
C
      INCLUDE 'error.for'
C     error.for
      INCLUDE 'sep.for'
C     sep.for
      INCLUDE 'forms.for'
C     forms.for
      INCLUDE 'length.for'
C     length.for
      INCLUDE 'sinv.for'
C     sinv.for
      INCLUDE 'mfsd.for'
C     mfsd.for
C
C=======================================================================
C